mirror of
https://github.com/PaperMC/Paper.git
synced 2024-11-23 23:57:43 +01:00
bc0dd0df3d
Upstream has released updates that appear to apply and compile correctly. This update has not been tested by PaperMC and as with ANY update, please do your own testing Bukkit Changes: 716b4fce Revert SnakeYAML upgrade ca6f8942 Update to Minecraft 1.18-rc3 57e7e952 #683: Add Player#showDemoScreen CraftBukkit Changes: c98abfb0 Update to Minecraft 1.18-rc3 9b258501 #960: Add Player#showDemoScreen d9542247 Produce remapped jars after bootstrap jar 99f3ddde SPIGOT-6808: Fix RegionAccessor#getBiome Spigot Changes: b7a4222e Update to Minecraft 1.18-rc3
119 lines
3.3 KiB
Text
119 lines
3.3 KiB
Text
plugins {
|
|
java
|
|
`maven-publish`
|
|
id("com.github.johnrengelman.shadow") version "7.1.0" apply false
|
|
id("io.papermc.paperweight.core") version "1.3.0-SNAPSHOT"
|
|
}
|
|
|
|
allprojects {
|
|
apply(plugin = "java")
|
|
apply(plugin = "maven-publish")
|
|
|
|
java {
|
|
toolchain {
|
|
languageVersion.set(JavaLanguageVersion.of(17))
|
|
}
|
|
}
|
|
}
|
|
|
|
subprojects {
|
|
tasks.withType<JavaCompile> {
|
|
options.encoding = Charsets.UTF_8.name()
|
|
options.release.set(17)
|
|
}
|
|
tasks.withType<Javadoc> {
|
|
options.encoding = Charsets.UTF_8.name()
|
|
}
|
|
tasks.withType<ProcessResources> {
|
|
filteringCharset = Charsets.UTF_8.name()
|
|
}
|
|
|
|
if (name == "Paper-MojangAPI") {
|
|
return@subprojects
|
|
}
|
|
|
|
repositories {
|
|
mavenCentral()
|
|
maven("https://papermc.io/repo/repository/maven-public/")
|
|
}
|
|
}
|
|
|
|
repositories {
|
|
mavenCentral()
|
|
maven("https://papermc.io/repo/repository/maven-public/") {
|
|
content { onlyForConfigurations("paperclip") }
|
|
}
|
|
}
|
|
|
|
dependencies {
|
|
paramMappings("net.fabricmc:yarn:1.18-rc3+build.1:mergedv2")
|
|
remapper("net.fabricmc:tiny-remapper:0.7.0:fat")
|
|
decompiler("net.minecraftforge:forgeflower:1.5.498.22")
|
|
paperclip("io.papermc:paperclip:3.0.0-SNAPSHOT")
|
|
}
|
|
|
|
paperweight {
|
|
minecraftVersion.set(providers.gradleProperty("mcVersion"))
|
|
serverProject.set(project(":paper-server"))
|
|
|
|
paramMappingsRepo.set("https://maven.fabricmc.net/")
|
|
remapRepo.set("https://maven.fabricmc.net/")
|
|
decompileRepo.set("https://files.minecraftforge.net/maven/")
|
|
|
|
paper {
|
|
spigotApiPatchDir.set(layout.projectDirectory.dir("patches/api"))
|
|
spigotServerPatchDir.set(layout.projectDirectory.dir("patches/server"))
|
|
|
|
mappingsPatch.set(layout.projectDirectory.file("build-data/mappings-patch.tiny"))
|
|
reobfMappingsPatch.set(layout.projectDirectory.file("build-data/reobf-mappings-patch.tiny"))
|
|
|
|
reobfPackagesToFix.addAll(
|
|
"co.aikar.timings",
|
|
"com.destroystokyo.paper",
|
|
"com.mojang",
|
|
"io.papermc.paper",
|
|
"net.kyori.adventure.bossbar",
|
|
"net.minecraft",
|
|
"org.bukkit.craftbukkit",
|
|
"org.spigotmc"
|
|
)
|
|
}
|
|
}
|
|
|
|
tasks.generateDevelopmentBundle {
|
|
apiCoordinates.set("io.papermc.paper:paper-api")
|
|
mojangApiCoordinates.set("io.papermc.paper:paper-mojangapi")
|
|
libraryRepositories.addAll(
|
|
"https://repo.maven.apache.org/maven2/",
|
|
"https://libraries.minecraft.net/",
|
|
"https://papermc.io/repo/repository/maven-public/",
|
|
"https://maven.fabricmc.net/",
|
|
)
|
|
}
|
|
|
|
publishing {
|
|
if (project.providers.gradleProperty("publishDevBundle").forUseAtConfigurationTime().isPresent) {
|
|
publications.create<MavenPublication>("devBundle") {
|
|
artifact(tasks.generateDevelopmentBundle) {
|
|
artifactId = "dev-bundle"
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
allprojects {
|
|
publishing {
|
|
repositories {
|
|
maven("https://papermc.io/repo/repository/maven-snapshots/") {
|
|
name = "paperSnapshots"
|
|
credentials(PasswordCredentials::class)
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
tasks.register("printMinecraftVersion") {
|
|
doLast {
|
|
println(providers.gradleProperty("mcVersion").get().trim())
|
|
}
|
|
}
|